Builder.coffee

################################################################################
#
#	Better
#
#	Builds the Better data for the site and the apps.
#
#	Updates the repositories, runs the Blockdown parser on the content, and
#	applies the respective theme.
#
#	This is Independent Technology.
#
#	▲❤ We practice Ethical Design (https://ind.ie/ethical-design)
#
#	© Aral Balkan. © Ind.ie. All Rights Reserved.
#	Released with love by Ind.ie under GNU AGPLv3 or later.
#	Free as in freedom. Please see the LICENSE file.
#
################################################################################

spawn = require('child-process-promise').spawn
path = require 'path'

winston = require 'winston'

app = require './App'

Blockdown = require './Blockdown'
NodeGit = require 'nodegit'

exec = (require 'child_process').exec

touch = require 'touch'

Cache = require './Cache2'

Promise = require 'thrush'

WebkitContentBlockerRulesToEasyList = require './WebkitContentBlockerRulesToEasyList'

class Builder
	instance = null

	log: null

	# This is the authorisation object we send
	authorisation: null

	sshPath: null
	privateSSHKeyPath: null
	publicSSHKeyPath: null

	constructor: ->
		# Singleton access.
		if instance
			return instance

		# Set up logging.
		logFile = path.join app.logsDirectory, 'Builder.log'
		@log = new winston.Logger
			transports:
				[
					new (winston.transports.Console)({ level: 'info' , formatter: (options) -> return options.message})
					new (winston.transports.File)({ filename: logFile, level: 'debug' })
				]

		# Convenience: important paths
		@sshPath = path.join app.privateDirectory, 'ssh'
		@privateSSHKeyPath = path.join @sshPath, 'id_rsa'
		@publicSSHKeyPath = path.join @sshPath, 'id_rsa.pub'

		# Create the authorisation object (that we use when making calls to the origin remotes
		# on source.ind.ie)
		@authorisation =
			callbacks:
				credentials: (url, userName) =>
					@log.info "Providing credentials: #{url}, #{userName}"
					NodeGit.Cred.sshKeyNew userName, @publicSSHKeyPath, @privateSSHKeyPath, ''
				# certificateCheck: () ->
				# 	return 1

		# Save reference to the singleton instance and return it.
		instance = @
		return instance


	#
	# Start a build.
	#
	build: =>
		@updateCache()
			.then @pullContentRepository
			.then @pullThemesRepository
			.then @renderBlockdown
			.then @updateRepositories
			.then =>
				@log.info "\t✓ Blockdown content ready."

				# If the app is running in development, fire off a
				# notification to let people know that rendering is done.
				exec "osascript -e 'display notification \"♥ Ready\" with title \"Better\" sound name \"Ping\"'"

				# Touch a file to signal that the build is complete.
				# (Used by the installer on the first run to know
				# when to continue with the installation process.)
				touch.sync (path.join app.homeDirectory, '.private', 'last-build-stamp')

		.catch (e) =>
			# If the app is running in development, fire off a
			# notification to let people know that rendering is done.
			exec "osascript -e 'display notification \"✗ Error\" with title \"Better\" sound name \"Basso\"'"

			@log.error "Build error.\n\n#{e}"
			console.trace()
			process.exit 1

	#
	# Update the cache.
	#
	updateCache: =>
		Promise.try =>
				(new Cache).build()

	#
	# Render content in Blockdown format.
	#
	renderBlockdown: =>

		startTime = new Date

		# @log.info 'Rendering content…'
		blockdown = new Blockdown

		easyListConverter = new WebkitContentBlockerRulesToEasyList

		blockdown.renderDataForSite()
		.then =>
			@log.info "\t✓ Rendered content for site."
			easyListConverter.convert()
			.then =>
				@log.info "\t✓ Rendered EasyList version."
				
				duration = ((new Date) - startTime)
				durationUnit = "ms"
				if duration > 1000
					duration = duration / 1000
					durationUnit = "seconds"

				@log.info "\t✓ Render complete. (#{duration} #{durationUnit})"


	#
	# Returns the latest content repository changes.
	# (Fetches and merges the latest changes from the content repository.)
	#
	pullContentRepository: =>
		@log.debug 'Pulling content repository.'
		return @pullRepository app.contentDirectory
			.then ->
				app.refreshContentIndex()


	#
	# Pulls the theme repository at the given path and then refreshes the themes.
	#
	pullThemesRepository: (repositoryDirectory) =>
		@pullRepository app.themesDirectory
			.then ->
				app.loadThemes()

	#
	# Returns the latest content repository changes for the repository at the given path.
	# (Fetches and merges the latest changes.)
	#
	pullRepository: (repositoryDirectory) =>
		repository = null

		# Perform a pull (fetch + merge), based on
		# https://github.com/nodegit/nodegit/blob/master/examples/pull.js
		NodeGit.Repository.open repositoryDirectory
			.then (repo) =>
				# Fetch
				repository = repo
				return repository.fetch 'origin', @authorisation
			.then =>
				# Merge
				repository.mergeBranches 'master', 'origin/master'
			.catch (e) =>
				@log.error "Build error.\n\n#{e}"
				console.trace()
				process.exit 1

	#
	# Updates the data for site and apps repositories.
	#
	updateRepositories: =>

		# @log.info 'Updating the data repositories for the app and the site…'

		@updateRepository app.dataForSiteDirectory
			.then =>
				@log.info "\t✓ Data repository update for site complete."


	#
	# Update the requested repository at the repository path and push to the remote.
	#
	updateRepository: (repositoryPath) =>

		repository = null
		index = null
		signature = NodeGit.Signature.now 'Better Builder', 'hello+better+builder@ind.ie'

		indexTreeOid = null
		siteURL = null

		NodeGit.Repository.open repositoryPath
			.then (repositoryResult) =>
				@log.debug "Update: got repository open result for #{repositoryPath}"
				repository = repositoryResult
				repository.index()
			.then (indexResult) =>
				@log.debug 'Update: got index result'
				index = indexResult
				index.read 1	# Force a read of the index into memory.
				# The ADD_CHECK_PATHSPEC should make addAll function like
				# git add --all (according to https://libgit2.github.com/libgit2/#HEAD/group/index/git_index_add_all)
				index.addAll '*', NodeGit.Index.ADD_OPTION.ADD_CHECK_PATHSPEC
				# DEBUG: Dry run
				# index.addAll '*', NodeGit.Index.ADD_OPTION.ADD_CHECK_PATHSPEC, (path, matchedPathSpec, payload) =>
				# 	@log.info "Path:"
				# 	@log.info path
				# 	@log.info "matchedPathSpec:"
				# 	@log.info matchedPathSpec
				# 	@log.info "payload:"
				# 	@log.info payload
				# 	return 1

			.then (result) =>
				writeResult = index.write() # sync
				index.writeTree()
			.then (writeTreeOidResult) =>
				indexTreeOid = writeTreeOidResult
				# Get the parent reference in the next two steps
				# (Courtesy Rafael: http://stackoverflow.com/a/28890806/253485)
				NodeGit.Reference.nameToId repository, 'HEAD'
			.then (head) =>
				repository.getCommit head
			.then (parent) =>
				repository.createCommit 'HEAD', signature, signature, 'Latest generated content.', indexTreeOid, [parent]
			.then (commitOidResult) =>
				NodeGit.Remote.lookup repository, 'origin'
			.then (origin) =>
				# NodeGit.Remote.initCallbacks @authorisation
				origin.push ['refs/heads/master:refs/heads/master'], 
				{ 
					credentials: @authorisation,
					pushUpdateReference: (ref, status, data) ->
						@log.debug "Push result status: #{status}"
				}
				# null,
				# repository.defaultSignature()
				# 'Push to master'
			.then (pushResult) =>
				@log.debug "site.origin push result: #{pushResult}"
				if repositoryPath == app.dataForSiteDirectory
					@pushToSite repository
			.then =>
				@log.debug "Repository update complete for: #{repositoryPath}"
			.catch ((e) =>
				@log.error "Git error: #{e}")


	#
	# Pushes to the site.
	#
	pushToSite: (repository) =>

		siteURL = null

		NodeGit.Remote.lookup repository, 'site'
			.then (site) =>
				siteURL = site.url()
				@log.debug "Got site: #{siteURL}"

				# NodeGit.Remote.initCallbacks @authorisation
				site.push ['refs/heads/master:refs/heads/master'], @authorisation
					# null,
					# repository.defaultSignature()
					# 'Push to master'
			.then (pushResult) =>
				@log.debug "Site push result: #{pushResult}"

				# If we pushed locally, we must manually trigger the post-receive hook.
				# (Nodegit — actually libgit2 — doesn’t trigger web hooks but, according to
				# the discussion below, it would not have triggered the post-receive hook
				# anyway as that’s the responsibility of the app.)
				#
				# (See https://github.com/libgit2/libgit2/issues/964#issuecomment-109998760)
				if siteURL[0] == '/'
					siteLocalPostReceiveHooksPath = path.join app.homeDirectory, '.private', 'site-local', 'data.git', 'hooks'
					siteLocalPostReceiveHookPath = path.join siteLocalPostReceiveHooksPath, 'post-receive'
					@log.debug "We pushed locally, about to manually trigger the post-receive hook at #{siteLocalPostReceiveHookPath}"
					spawn siteLocalPostReceiveHookPath, [], {cwd:siteLocalPostReceiveHooksPath}
						.progress (childProcess) =>
							@log.debug "Child process running with ID: #{childProcess.pid}"
							childProcess.stdout.on 'data', (data) =>
								@log.debug "Child stdout: #{data.toString()}"
							childProcess.stderr.on 'data', (data) =>
								@log.debug "Child stderr: #{data.toString()}"
						.then =>
							@log.debug "Local push complete."
						.fail (error) =>
							@log.error "Local push failed with error: #{error}"

				@log.debug 'Completed update.'

module.exports = Builder